Файл:Zahl der Erstanträge auf Asyl (Eurostat).svg
Перейти до навігації
Перейти до пошуку
Розмір цього попереднього перегляду PNG для вихідного SVG-файлу: 800 × 400 пікселів. Інші роздільності: 320 × 160 пікселів | 640 × 320 пікселів | 1024 × 512 пікселів | 1280 × 640 пікселів | 2560 × 1280 пікселів.
Повна роздільність (SVG-файл, номінально 800 × 400 пікселів, розмір файлу: 30 КБ)
|
Відомості про цей файл містяться на Вікісховищі — централізованому сховищі вільних файлів мультимедіа для використання у проектах Фонду Вікімедіа. |
.svg){kind=link}
Опис файлу
| Опис |
Deutsch: Anzahl der Asylanträge in der EU insgesamt (Schwarzweißer Graph) und von 9 europäschen Ländern (nicht alle Mitgl. EU). Zuordnung zu den farbigen Flächen von unten nach oben: D F GB IT GR ES SE AU CH |
| Джерело | Власна робота - Zahlen: Eurostat [1] & Übersicht [2] |
| Автор | Summer ... hier! (обговорення) 17:36, 4 November 2017 (UTC) |
![[1]](https://ec.europa.eu/eurostat/statistics-explained/index.php?title=File:First_time_asylum_applicants,_Q4_2016_%E2%80%93_Q4_2017.png){kind=link}
Ліцензування
|
Власник авторських прав на цей файл, Eurostat, дозволяє використовувати файл для будь-яких цілей, при умові збереження інформації про власника авторських прав. Дозволяється розповсюдження цього файлу, створення похідних робіт, а також комерційне та будь-яке інше використання. |
Зазначення авторства:
Eurostat (year)
|
This media file was created by Eurostat, the European Statistical Office and a Directorate-Generale of the EU Commission.
Under Eurostat's Copyright Notice and Free Re-Use of Data, they encourage free re-use of its data, both for non-commercial and commercial purposes. All statistical data, metadata, content of web pages or other dissemination tools, official publications and other documents published on its website, with the exceptions listed below, can be reused without any payment or written licence provided that:
|
 |
Я, власник авторських прав на цей твір, добровільно публікую його на умовах такої ліцензії:
 
|
Цей файл доступний на умовах Creative Commons CC0 1.0 Universal Public Domain Dedication. |
| Особа, що пов'язала роботу з даною дією, передала роботу у суспільне надбання шляхом відмови від усіх своїх прав на роботу по всьому світу по закону про авторське право, включаючи всі пов'язані і суміжні права, в тій мірі, що допускається законом.
Ви можете копіювати, змінювати, розповсюджувати і виконувати роботу, навіть на комерційній основі, не питаючи дозволу. |
Gnuplot script to generate this plot
Це векторне зображення було створено з допомогою Gnuplot.
W3C-validity not checked.
#!/usr/bin/gnuplot
# gnuplot
# Daten per Here-Document
# (zur tech. Beschreibung siehe Abschntt 'Inline data and datablocks'
# in http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HereDoc << EndOfData
# Quelle:
# https://de.wikipedia.org/wiki/Fl%C3%BCchtlingskrise_in_Europa_ab_2015#Zahlen_und_Fakten
# bzw.
# https://de.wikipedia.org/w/index.php?title=Fl%C3%BCchtlingskrise_in_Europa_ab_2015&oldid=179136851
#
# Datum EU D F GB IT GR ES SE AU CH
#
01.01.2008; 225150; 26845; 41840; 31290; 30140; 19885; 4515; 24785; 12715; 16520
01.01.2009; 263835; 32910; 47620; 31665; 17640; 15925; 3005; 24175; 15780; 15900
01.01.2010; 259400; 48475; 52725; 24335; 10000; 10275; 2740; 31850; 11045; 15425
01.01.2011; 309040; 53235; 57330; 26915; 40315; 9310; 3420; 29650; 14420; 23615
01.01.2012; 335290; 77485; 61440; 28800; 17335; 9575; 2565; 43855; 17415; 28400
01.01.2013; 431090; 126705; 66265; 30585; 26620; 8225; 4485; 54270; 17500; 21305
01.01.2014; 626960; 202645; 64310; 32785; 64625; 9430; 5615; 81180; 28035; 23555
01.01.2015; 1322825; 476510; 76165; 40160; 83540; 13205; 14780; 162450; 88160; 39445
01.01.2016; 1259955; 745155; 84270; 38785; 122960; 51110; 15755; 28790; 42255; 27140
01.01.2017; 649855; 198255; 91070; 33310; 126550; 57020; 30455; 22190; 22160; 16615
#
EndOfData
# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y" # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator
# Allgemeines zur Ausgabe
unset key
set key vertical maxrows 6
set key left top # Legende link oben
set style data lines
set style fill transparent solid 1.0 noborder
set grid
# Bereiche/Format/etc X-Achse
set xdata time
set xlabel 'Jahr'
set xrange ['01.01.2008':'01.01.2017']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 1
# xtics in Sekunden
# der Beginn der X-Einteilung kann außerhalb xrange
# liegen
set mxtics 1 # Unterteilung der Skalierung
set xtics nomirror # Nur unten Skalieren
set format x '%Y' # Beschriftungsformat JJJJ
set xtics out # Skal. aussen da sie sonst von Grafik überschr. wird
# Bereiche/Format/etc Y-Achse
set ylabel 'Asylanträge'
set ylabel offset 2.5, 0.0 # Beschriftung näher an die Y-Achse
set yrange [0:]
set ytics 250000
set mytics 5
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set format y "%'.0f" # Ausgabeformat
set ytics out # Skal. aussen da sie sonst von Grafik überschr. wird
# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,16"
# keine "set output '<Dateiname>'" Angabe
# Abkürzungen:
# rgb : red-green-blue
# fs : fillstyle
# filledc : filledcurves
# lc : linecolor
# lp : linespoints
# lt : linetype
# w : with
# lw : linewidth
# pt : pointtype
# ps : pointsize
# usi : using
# ti : title
# Erzeugen der Ausgabe (zum Anlegen der Datei 'daten.scv' siehe unten)
plot \
$my_HereDoc usi 1:($3+$4+$5+$6+$7+$8+$9+$10+$11) ti 'CH' w filledc below x1 lt rgb '#CC0000', \
$my_HereDoc usi 1:($3+$4+$5+$6+$7+$8+$9+$10 ) ti 'AU' w filledc below x1 lt rgb '#00CC00', \
$my_HereDoc usi 1:($3+$4+$5+$6+$7+$8+$9 ) ti 'SE' w filledc below x1 lt rgb '#0000CC', \
$my_HereDoc usi 1:($3+$4+$5+$6+$7+$8 ) ti 'ES' w filledc below x1 lt rgb '#FF00FF', \
$my_HereDoc usi 1:($3+$4+$5+$6+$7 ) ti 'GR' w filledc below x1 lt rgb '#00FFFF', \
$my_HereDoc usi 1:($3+$4+$5+$6 ) ti 'IT' w filledc below x1 lt rgb '#FFFF00', \
$my_HereDoc usi 1:($3+$4+$5 ) ti 'GB' w filledc below x1 lt rgb '#FF8888', \
$my_HereDoc usi 1:($3+$4 ) ti 'F' w filledc below x1 lt rgb '#880088', \
$my_HereDoc usi 1:($3 ) ti 'D' w filledc below x1 lt rgb '#8888FF', \
$my_HereDoc usi 1:($2) ti 'EU' w lp lc '#000000' lt 1 lw 2.5 pt 7 ps 0.6
quit
Історія файлу
Клацніть на дату/час, щоб переглянути, як тоді виглядав файл.
| Дата/час | Мініатюра | Розмір об'єкта | Користувач | Коментар | |
|---|---|---|---|---|---|
| поточний | 19:05, 23 червня 2018 | | 800 × 400 (30 КБ) | Summer ... hier! | yLabel näher an yAchse |
| 19:55, 23 квітня 2018 |  | 800 × 400 (30 КБ) | Summer ... hier! | +Daten 2017 | |
| 01:03, 4 січня 2018 |  | 800 × 400 (36 КБ) | Summer ... hier! | Schriftfont 16 statt 14 | |
| 00:22, 6 листопада 2017 |  | 800 × 400 (36 КБ) | Summer ... hier! | Legende | |
| 17:36, 4 листопада 2017 |  | 800 × 400 (33 КБ) | Summer ... hier! | {{Information |Description = {{de|Anzahl der Asylanträge in der EU insgesamt (Schwarzweißer Graph und nach 11 Ländern) }} |Source = {{own}} |Author = ~~~~ |Date = }} == {{int:license-header}} == {{self|Cc-zero}} == Gn... |
Використання файлу
Такі сторінки використовують цей файл:
Глобальне використання файлу
Цей файл використовують такі інші вікі:
.svg){kind=link}